Un message est simplement un nom et une éventuelle liste d'arguments. A partir des messages, le programmeur construit des petits phrases (les badinages Smalltalk). Pour ce faire il existe trois types de message : les messages unaire, binaire et à mot clé.

Message unaire

Le message unaire est le plus simple, il est envoyé à un objet sans argument, l'écriture du message suit directement celle de l'objet (le receveur). Par exemple, pour demander à un nombre son cosinus, nous lui envoyons simplement le message cos :

0.5 cos
-->  0.877582561890373

( 1 + 2i ) cos 
--> 2.032723007019665 - 3.0518977991518 i

#( 0 0.5 ) cos
--> #(1.0 0.877582561890373)

Le même message est envoyé à des objets (les receveurs) de différentes natures (respectivement instances des classes Float, Complex et Array). A la réception du message, le receveur décide du traitement à appliquer.

Dans une chronique précédente, nous avions introduit les objets durée que nous pouvons créer en envoyant le message unaire seconds à un nombre :

90 seconds
--> 0:00:01:30

Message binaire

Un message binaire est envoyé à un objet avec un seul argument. L'écriture du message suit celle du receveur suivi d'un objet, l'argument. Par exemple, pour ajouter deux nombres, nous utilisons le message binaire + :

5 + 2
--> 7

L'addition n'est donc pas un opérateur défini dans le langage, c'est une méthode définie dans les classes souhaitant répondre à ce message. Ainsi des objets comme des durées répondent à ce message :

90 seconds + 30 seconds
--> 0:00:02:00

Dans l'expression ci-dessus, il y a trois messages. Il faut savoir que les messages unaires sont prioritaires sur les messages binaires, l'exécution se fait donc dans l'ordre suivant :

  1. 90 seconds --> Duration 0:00:01:30
  2. 30 seconds --> Duration 0:00:00:30
  3. le message + est envoyé à l'instance Duration 0:00:01:30 avec comme argument l'instance Duration 0:00:00:30

Les objets couleurs répondent aussi à ce message pour mélanger des couleurs :

Color red + Color blue
--> Color magenta

Quelle est la priorité lorsque une expression comporte plusieurs messages binaires ? En cas d'égalité de priorité, l'exécution se fait de gauche à droite. Ainsi

4 + 5 * 4
--> 36

est arithmétiquement équivalent à ( 4 + 5 ) * 4. Puisque les opérateurs n'existent pas en tant que tel dans le langage Smalltalk, il n'y a pas non plus de notion de priorité des opérateurs. Pour obtenir la priorité souhaitée, utiliser des parenthèses :

4 + ( 5 * 4 )
--> 24

Message à mot clé

Un message à mot clé est envoyé à un receveur avec plusieurs arguments, les arguments sont intercalés entre les différentes composantes du message à mot clé. Par exemple, pour définir une couleur à partir de ses composantes rouge, verte et bleue nous envoyons le message r:g:b: à l'objet Color :

Color r: 1 g: 0 b: 0
--> Color red

Point x: 5 y: 0.5
--> 5@0.5

La deuxième expression définit un point de coordonnées (5 ; 0.5) en utilisant le message x:y: envoyé à la classe Point. Noter qu'un point se définit aussi avec le message binaire @ envoyé à un nombre avec un autre nombre comme argument.

Le message à mot clé est de priorité inférieure à celle des messages unaire et binaire. L'ordre de priorité des messages est donc :

message unaire > message binaire > message à mot clé

Pour définir notre point, nous pouvons donc écrire :

Point x: 5 y: 1 / 2

mais les parenthèses sont nécessaires lorsque nous utilisons le message @ pour définir notre point ;

5 @ ( 1 / 2 )

Sans les parenthèses l'expression aura un autre sens, explicitée ici avec les parenthèses :

( 5 @ 1 ) / 2

C'est une expression valide car un point comprend le message /, le résultat est le point ( 5 / 2) @ (1 / 2)

Exemple de composition

Pour en revenir au badinage, voici une recette d'un quatre quarts écrite en Smalltalk :

preparation := Recette new.
preparation ajoute: 200 g de: Sucre.
preparation ajoute: 200 g de: Farine.
preparation ajoute: 20 g de: Levure.
preparation ajoute: 3 de: Oeuf.
preparation melange.
preparation cuisson: 45 minutes

Les arguments Sucre, Farine, Levure et Oeuf sont des classes manipulables comme tout autre objet. En Smalltalk les classes sont des objets de première classe.

Conclusion

Notre rapide panorama des messages s'achève ici. Pour compléter cette mise en bouche, je vous invite à la lecture du livre Squeak par l'exemple.

That's all folks!